float angleX,angleY,bangleX,bangleY,tempo,rayon,epais,cote,cost,sint;
	Polyedre licosaedre;
	Vecteur coul,origine1,origine2,axerot;
//	++++++++++++++++++++++++++++++++++++++++
//	++++++++++++++++++++++++++++++++++++++++	
void setup(){
	size(750,500);
	tempo=0;
	rayon=2000;
	licosaedre=new Polyedre(rayon);
	coul=new Vecteur(0,0.6f,1.8f);
	origine1=new Vecteur(0,1800,-15000);
	origine2=new Vecteur(0,0,-15000);	
	axerot=new Vecteur(1,0,1).normalize();
}
//	++++++++++++++++++++++++++++++++++++++++
//	++++++++++++++++++++++++++++++++++++++++
void loop(){

	clear();background(191,191,170);

	modifierparam();
	Vecteur.afficherRepere(this,2000);

	box(12000);

	licosaedre.dessiner(licosaedre.patron,true);
	licosaedre.evoluer();	
}
//	++++++++++++++++++++++++++++++++++++++++
//	++++++++++++++++++++++++++++++++++++++++
void modifierparam(){

	translate(origine1.x,origine1.y,origine1.z);
	bangleX=(mouseY)/50.0f;
	bangleY=(mouseX)/50.0f;//	
	angleX+=(bangleX-angleX)/10.0f;
	angleY+=(bangleY-angleY)/10.0f;
	rotateX(-angleX);
	rotateY(angleY);	
}
//++++++++++++++++++++++++++++++++++++++++
//++++++++++++++++++++++++++++++++++++++++
void mousePressed(){
	licosaedre=new Polyedre(rayon);
}
//++++++++++++++++++++++++++++++++++++++++
//++++++++++++++++++++++++++++++++++++++++
Vecteur vecteurNormal(Vecteur v1,Vecteur v2,Vecteur v3){
	Vecteur w1=v2.ajouter(v1,-1);
	Vecteur w2=v3.ajouter(v1,-1);	
	Vecteur res=(w1.cross(w2));
	return res.normalize();	
}
//	++++++++++++++++++++++++++++++++++++++++
//					CLASSE POLYEDRE
//	++++++++++++++++++++++++++++++++++++++++
class Polyedre{
	float r,angle,diedre,tempi;
	Vector patron,volume;
	boolean enmouvement;
	Vecteur axe;
	public Polyedre(float ray){
		r=ray;
		patron=new Vector();
		volume=new Vector();
		diedre=(float)Math.acos(sqrt(5)/3);
		enmouvement=false;
		tempi=0;
		axe=new Vecteur(1,0,0);
		for(int i=0;i<4;i++){
			patron.addElement(
			new Face(
				new Vecteur(0,0,0),
				new Vecteur(r*cos((i+1)*PI/3),0,r*sin((i+1)*PI/3)),
				new Vecteur(r*cos(i*PI/3),0,r*sin(i*PI/3)))			
			);
		}
		patron.addElement(
		new Face(
			new Vecteur(r*cos(5*PI/3),0,r*sin(5*PI/3)),	
			new Vecteur(r*cos(4*PI/3),0,r*sin(4*PI/3)),
	
			new Vecteur(0,0,0)		
		));
		
		for(int i=0;i<5;i++){
			patron.addElement(
			new Face(
				new Vecteur(r*cos(5*PI/3)+r*i,0,r*sin(5*PI/3)),
				new Vecteur(r*i,0,2*r*sin(5*PI/3)),
				new Vecteur(r*cos(4*PI/3)+r*i,0,r*sin(4*PI/3)))			
			);
			if(i<4)patron.addElement(
			new Face(
				new Vecteur(r*cos(5*PI/3)+r*i,0,r*sin(5*PI/3)),
				new Vecteur(r*i+r,0,2*r*sin(5*PI/3)),
				new Vecteur(r*i,0,2*r*sin(5*PI/3)))			
			);				
			
		}
		patron.addElement(new Face(	
			new Vecteur(5*r,0,2*r*sin(5*PI/3)),
			new Vecteur(4*r,0,2*r*sin(5*PI/3)),
			new Vecteur(r*4.5f,0,r*sin(5*PI/3)))			
		);	
		
		for(int i=1;i>-4;i--){
			patron.addElement(
			new Face(
				new Vecteur(4.5f*r+r*cos(i*PI/3),  	0,		3*r*sin(5*PI/3)+r*sin(i*PI/3)),
				new Vecteur(4.5f*r,	                    0,		3*r*sin(5*PI/3)),
				new Vecteur(4.5f*r+r*cos((i+1)*PI/3),  0,		3*r*sin(5*PI/3)+r*sin((i+1)*PI/3)))			
			);
		}				
	}
//	++++++++++++++++++++++++++++++++++++++++	

void dessiner(Vector desfaces,boolean bool){
	if(bool){stroke(255);}else{noStroke();}	
	for(int i=0;i<desfaces.size();i++){
		Face fa=(Face)desfaces.elementAt(i);
		dessinerTriangle(fa.points[0],fa.points[1],fa.points[2],i);
	}	
}
void dessiner0(Vector desfaces,boolean bool){
	tempi+=0.05;
	if(bool){stroke(255);}else{noStroke();}	
	for(int i=0;i<desfaces.size();i++){
		Face fa=(Face)desfaces.elementAt(i);
		Vecteur[] res= fa.rotationAxiale(origine2,axerot,tempi);
		dessinerTriangle(res[0],res[1],res[2],i);
	}	

}
//	++++++++++++++++++++++++++++++++++++++++

void evoluer(){
if(patron.size()>0){
	if(!enmouvement){	
		Face f=(Face)patron.remove(0);
		volume.add(0,f);
		angle=0;
		enmouvement=true;
	}else{
		angle+=0.06;
		if(angle>diedre){
			angle=diedre;
			enmouvement=false;
	}
	Face f0=(Face)volume.elementAt(0);

	for(int i=0;i<volume.size();i++){
		Face ff=(Face)volume.elementAt(i);
		Vecteur[] res=ff.rotationAxiale( f0.centre,f0.axe,angle );
		if(abs(angle-diedre)<0.001f){
			((Face)volume.elementAt(i)).points[0]=res[0];
			((Face)volume.elementAt(i)).points[1]=res[1];	
			((Face)volume.elementAt(i)).points[2]=res[2];	
		 }
		 dessinerTriangle(res[0],res[1],res[2],i);

	}
	noFill();
	}
	}else{
	dessiner0(volume,false);}
}


void dessinerTriangle(Vecteur v0,Vecteur v1,Vecteur v2,int i){
	Vecteur no=vecteurNormal(v0,v1,v2);
	float scal=1-abs(Vecteur.dot(no,coul));
	noStroke();
	beginShape(TRIANGLES);
		fill(150+100*scal,80+scal*175,10*i+55*scal);
			vertex(v0.x,v0.y,v0.z);
		fill(130+120*scal,10*i+scal*55,130+105*scal);	
			vertex(v1.x,v1.y,v1.z);	
		fill(10*i+50*scal,80+scal*175,150+105*scal);		
			vertex(v2.x,v2.y,v2.z);		
	endShape();
	noFill();	
}
}
//	++++++++++++++++++++++++++++++++++++++++
//                                       			CLASSE FACE
//	++++++++++++++++++++++++++++++++++++++++
class  Face{
	
	Vecteur[] points;			//table des sommets
	Vecteur centre,axe;		//les éléments qui définissent l'axe de rotation associé
			
//	++++++++++++++++++++++++++++++++++++++++
	
public Face(Vecteur p0,Vecteur p1,Vecteur p2){
	points =new Vecteur[] {p0,p1,p2};
	centre=p0;
	axe=(p1.ajouter(p0,-1)).normalize();
}
//	++++++++++++++++++++++++++++++++++++++++
						//dessine le triangle avec des couleurs corrigées par le vecteur normal
public void afficher(int i){	
	Vecteur no=vecteurNormal(points[0],points[1],points[2]);
	float scal=1-abs(Vecteur.dot(no,coul));
	beginShape(POLYGON);
			fill(150+100*scal,80+scal*175,55*scal+10*i);
				vertex( points[0].x, points[0].y-epais ,points[0].z );
			fill(130+120*scal,10*i+scal*55,105*scal+130);
				vertex( points[1].x, points[1].y-epais ,points[1].z );
			fill(10*i+50*scal,80+scal*175,150+105*scal);	
				vertex( points[2].x, points[2].y-epais ,points[2].z );
	endShape(); 
	noFill();	
}
//	++++++++++++++++++++++++++++++++++++++++
			//rotationAxiale fait tourner  "face" autour d'une droite qui passe par "centre"
			// dont le vecteur directeur et l'angle sont définis dans le quaternion
Vecteur[] rotationAxiale(Vecteur centre,Vecteur axe,float angle){
	Quat q=new Quat(cos(angle/2),axe.mul(sin(angle/2)));	
	Vecteur v0=q.tourner(points[0].ajouter(centre,-1)).ajouter(centre,1);
	Vecteur v1=q.tourner(points[1].ajouter(centre,-1)).ajouter(centre,1);	
	Vecteur v2=q.tourner(points[2].ajouter(centre,-1)).ajouter(centre,1);	
	return new Vecteur[]{v0,v1,v2};
}
//	++++++++++++++++++++++++++++++++++++++++
}


//  -------------------------------------------------------------------------
//-------------------------------------------------------
static class Vecteur
{
public  float x, y, z;
 
public  Vecteur()
  {
  }

public  Vecteur(float x, float y, float z)
  {
    this.x = x;
    this.y = y;
    this.z = z;
 
  }
  
public  Vecteur(float x, float y, float z,float lon)
  { float no=(float) Math.sqrt(x * x + y * y + z * z);
  	no=lon/no;
    this.x = x*no;
    this.y = y*no;
    this.z = z*no;
 
  } 
  public void place(float xx, float yy, float zz)
  {
    this.x = xx;
    this.y = yy;
    this.z = zz;
 
  }
 public Vecteur normalize()
  {
    float length = length();
    x /= length;
    y /= length;
    z /= length;
    return this;
  }
  public  Vecteur normalize(float k)
   {
     float length = length();
     x=x/ length*k;
     y =y/ length*k;
     z =z/ length*k;
     return this;
   }
   public  float length()
  {
    return (float) Math.sqrt(x * x + y * y + z * z);
  }

  public  Vecteur cross(Vecteur v2)
  {
    Vecteur res = new Vecteur();
    res.x = y * v2.z - z * v2.y;
    res.y =z * v2.x - x * v2.z;
    res.z = x * v2.y - y * v2.x;
    return res;
  }

  public  static float dot(Vecteur v1, Vecteur v2)
  {
    return v1.x * v2.x + v1.y * v2.y + v1.z * v2.z;
  }
  public float dot(Vecteur v1)
  {
    return v1.x * x + v1.y *y + v1.z *z;
  }
  public Vecteur mul( float d)
  {
    Vecteur res = new Vecteur();
    res.x =x * d;
    res.y = y * d;
    res.z = z * d;
    return res;
  }
  public static Vecteur comb(float a,Vecteur v1,float b, Vecteur v2)
  {
   float  rx =a* v1.x + b*v2.x;
   float ry =a* v1.y + b*v2.y;
    float rz =a* v1.z + b*v2.z;
    return new Vecteur(rx,ry,rz);
  }
  public static Vecteur barycentre(float a,Vecteur v1,float b, Vecteur v2)
   {
   Vecteur res=comb(a,v1,b,v2);
   res=res.mul(1/(a+b));
     return res;
   }
  public  Vecteur ajouter(Vecteur v,float m){
		Vecteur res=new Vecteur(x+v.x*m, y+v.y*m,z+v.z*m);
    return res;
  }
  public  Vecteur ajouter(float ax,float ay,float az){
		 Vecteur res=new Vecteur(x+ax, y+ay,z+az);
     return res;
   }
  
  public  void afficher(String tex,BApplet ba){
  	ba.println(tex+"x= "+x+" y= "+y+" z= "+z);
  }
  public  Vecteur projete(Vecteur laxe){
  	laxe.normalize();
  	Vecteur res=laxe.mul(this.dot(laxe));
  	return res;
  }
  public Vecteur projeteSurAxe(Vecteur laxe){
	 laxe.normalize();
	 Vecteur res=laxe.mul(this.dot(laxe));
	 return res;
   }
   public  Vecteur projeteSurPlan(Vecteur laxe){
	  laxe.normalize();
	  Vecteur res=projeteSurAxe(laxe);
	  res=this.ajouter(res,-1);
	  return res;
    } 
    public  Vecteur symetrique(Vecteur laxe){
	    laxe.normalize();
	    Vecteur res=projeteSurAxe(laxe);
	    res=this.ajouter(res,-2.0f);
	    return res;
      }
     public float distancePointDroite(Vecteur d, Vecteur v){
		v.normalize();
	     	Vecteur pd=d.ajouter(this,-1);
	      	Vecteur hd=v.mul(v.dot(pd));
	    	 Vecteur ph=pd.ajouter(hd,-1);
	     	 return ph.length();
      } 
    /*projection sur le plan vectoriel de normale "laxe"
    public   Vecteur projeteSurPlan(Vecteur laxe,Vecteur unpoint){
	    laxe.normalize();
	    Vecteur res=projeteSurPlan(laxe);	   
	return  res.ajouter(unpoint.projeteSurAxe(res),1);
	   
      }*/
        
      public  float donneAngle(Vecteur vc){
	 return (float) Math.acos(this.dot(vc)/(length()*vc.length()));
  }
  
  public  Vecteur tourner(Vecteur axe,float angle){//axe est normé et orthogonal à this
  	Vecteur vaxe=axe.mul(this.dot(axe));
  	Vecteur vx=this.ajouter(vaxe,-1);
  	Vecteur ygrec=axe.cross(this);
  	return vaxe.ajouter(Vecteur.comb((float)Math.cos(angle),this,(float)Math.sin(angle),ygrec),1);
  }
  public Vecteur cloner()
    {
      Vecteur res = new Vecteur();
      res.x =x ;
      res.y = y ;
      res.z = z ;
      return res;
    } 
    public  Vecteur tourner(float a,Vecteur ax){
	    Quat qv=new Quat(0.0f,x,y,z);
	    Quat q0=new Quat((float)Math.cos(a/2),ax.mul((float)Math.sin(a/2)));
	    Quat qc=q0.conjugue();
	    Quat q1=Quat.mul(qv,qc);	
	    Quat q= Quat.mul(q0,q1);
	    return new Vecteur(q.x,q.y,q.z);	
	
    } 
    public  Vecteur coorabs(BApplet ba) {
	    float xa = ba.objectX(x,y,z);
	    float ya = ba.objectY(x,y,z);
	    float za = ba.objectZ(x,y,z);
	    return new Vecteur(xa, ya, za);
    }
//  *******************************************
//  *******************************************
//  *******************************************
    public static  void afficherRepere(BApplet ba,float lon){
       
	     ba.stroke(255,0,0);
	    ba.line(0,0,0,lon,0,0);
	    ba.stroke(0,255,0);    
	    ba.line(0,0,0,0,lon,0);
	    ba.stroke(0,0,255);   
	    ba.line(0,0,0,0,0,lon);          
       } 
public static  void afficherRepere(BApplet ba){
       
	 ba.stroke(255,0,0);
	ba.line(0,0,0,500,0,0);
	ba.stroke(0,255,0);    
	ba.line(0,0,0,0,500,0);
	ba.stroke(0,0,255);   
	ba.line(0,0,0,0,0,500);          
   } 
 

    public  void afficherLigne(float k,BApplet ba){
    	ba.line(x*k,y*k,z*k,-x*k,-y*k,-z*k);
}

    }
//  *******************************************
//  *******************************************
//------------------------------------------------------------
// Quat class
//------------------------------------------------------------
static  class Quat
{
  float w, x, y, z;

 public Quat()
  {
    reset();
  }

 public  Quat(float w, float x, float y, float z)
  {
    this.w = w;
    this.x = x;
    this.y = y;
    this.z = z;
  }
   public Quat(float w, Vecteur v)
  {
    this.w = w;
    this.x =v. x;
    this.y = v.y;
    this.z = v.z;
  }
  Quat(Quat q)
  {
    set(q);
  }

 public  void reset()
  {
    w = 1.0f;
    x = 0.0f;
    y = 0.0f;
    z = 0.0f;
  }

  public void set(float w, Vecteur v)
  {
    this.w = w;
    x = v.x;
    y = v.y;
    z = v.z;
  }

  public void set(Quat q)
  {
    w = q.w;
    x = q.x;
    y = q.y;
    z = q.z;
  }
public float norme(){
	return (float)Math.sqrt(x * x + y * y + z * z + w * w);
}

 public  Quat normalize()
  {
    float square = x * x + y * y + z * z + w * w;
    float dist = (square > 0.0f) ? (1.0f / (float) Math.sqrt(square)) : 1.0f;

    x *= dist;
    y *= dist;
    z *= dist;
    w *= dist;
    return this;
  }
  public  Quat normalize(float c)
   {
     float square = x * x + y * y + z * z + w * w;
     float dist = (square > 0.0f) ? (c / (float) Math.sqrt(square)) : c;
	
     x *= dist;
     y *= dist;
     z *= dist;
     w *= dist;
     return this;
   }
 public static Quat mul(Quat q1, Quat q2)
  {
    Quat res = new Quat();
    res.w = q1.w * q2.w - q1.x * q2.x - q1.y * q2.y - q1.z * q2.z;
    res.x = q1.w * q2.x + q1.x * q2.w + q1.y * q2.z - q1.z * q2.y;
    res.y = q1.w * q2.y + q1.y * q2.w + q1.z * q2.x - q1.x * q2.z;
    res.z = q1.w * q2.z + q1.z * q2.w + q1.x * q2.y - q1.y * q2.x;
    return res;
  }
 public static Quat comb(Quat q1,float r1, Quat q2,float r2)
   {
     Quat res = new Quat();
     res.w = q1.w *r1 +  q2.w*r2;
     res.x = q1.x * r1+  q2.x * r2;
     res.y = q1.y * r1+  q2.y * r2;
     res.z = q1.z * r1+  q2.z * r2;
     return res;
   }
   public Quat ajouter(Quat q1,float r1)
     {
       Quat res = new Quat();
       res.w = q1.w *r1;
       res.x = q1.x * r1;
       res.y = q1.y * r1;
       res.z = q1.z * r1;
       return res;
     }  
   
     public   float[] getValue()
 {	
   float[] res = new float[4];
   float nq=norme();
	 res[0] = (float) Math.acos(w/nq)* 2.0f;
  	 
	 float nV= (float) Math.sqrt(x*x+y*y+z*z);
  if ( nV< 0.00001f*nq)
   {
	res[1] = x ;
	res[2] = y;
	res[3] = z ;   
   }else{
	 res[1] = x /nV;
	 res[2] = y/nV ;
	 res[3] = z/nV;  }
   return res;
 }
 
 public   Quat conjugue(){
	return new Quat(w,-x,-y,-z);
}
public  Quat oppose(){
	return new Quat(-w,-x,-y,-z);
}
public Quat copie(){
	return new Quat(w,x,y,z);
	}
	public Quat copieNorme(){
		Quat res=new Quat(w,x,y,z);
		res.normalize();
		return res;
		}	
	public Vecteur tourner(Vecteur v){
	Quat qv=new Quat(0.0f,v.x,v.y,v.z);
	Quat qc=this.conjugue();
	Quat q1=Quat.mul(qv,qc);	
	Quat q= Quat.mul(this,q1);
	return new Vecteur(q.x,q.y,q.z);	
	
}
public static Quat slerp(Quat d, Quat a,float t){
	d.normalize();
	a.normalize();
	float angle=(float)Math.acos(d.x*a.x+d.y*a.y+d.z*a.z);
	float sina=(float)Math.sin(angle);
	float rd=(float)Math.sin(angle*(1-t))/sina;
	float ra=(float)Math.sin(angle*t)/sina;
	Quat res= Quat.comb(d,rd,a,ra);

	return res;

}
static Quat slerp1(Quat d, Quat a,float tt){
	d.normalize();
	a.normalize();
	float t=(tt-1)*(tt-1)*(tt-1)+1;
	float angle=(float)Math.acos(d.x*a.x+d.y*a.y+d.z*a.z);
	float sina=(float)Math.sin(angle);
	float rd=(float)Math.sin(angle*(1-t))/sina;
	float ra=(float)Math.sin(angle*t)/sina;
	Quat res= Quat.comb(d,rd,a,ra);

	return res;

}
public Vecteur axe(){
return new Vecteur(x,y,z);	
}



public static Quat euler2quat(float psi,float theta,float phi){
	/* psi      :angle de la rotation autour de 0z    :precession
	 * theta   :angle de la rotation autour de 0x1  :nutation
	 * phi      :angle de la rotation autoue de 0z2  : rotation propre
	 */
		float w,x,y,z,th,psiMphi,psiPphi;
		th=theta/2;
		psiMphi=(psi-phi)/2;
		psiPphi=(psi+phi)/2;		
		w=(float)Math.cos(th)*(float)Math.cos(psiPphi);
		x=(float)Math.sin(th)*(float)Math.cos(psiMphi);
		y=(float)Math.sin(th)*(float)Math.sin(psiMphi);
		z=(float)Math.cos(th)*(float)Math.sin(psiPphi);		
	return new Quat(w,x,y,z);
}

}