//___________________________________________
//ALCYS_CHOC_3D3    version du 28/04/2004
//___________________________________________
Systeme sys;
float anglx,angly;
Vecteur gabs;
void setup(){
  size(700,500);
  background(105,120,150);
  ellipseMode(CENTER_DIAMETER);
  rectMode(CENTER_DIAMETER);
  anglx=0;
  angly=0;
 gabs=new Vecteur(0,1000,0);
  sys=new Systeme(15);
}

void loop(){
  clear();
 
  
  angly += (float)(width/2-mouseX)/1000-angly*0.1;
  anglx += (float)(height/2-mouseY)/1000-anglx*0.1;
  
  //calcul de la gravite dans le repere de la boite
  push(); 
        rotateX(-anglx);  
        rotateY(-angly);
        Vecteur gbox=gabs.composantesAbs();
   pop();
   push();//stocker le contexte absolu
        translate(200,200,-1100);
        rotateY(angly);
        rotateX(anglx);
        sys.controleChocs(gbox);
        sys.montreBox(); 
  pop();//on revient dans le repere absolu

  sys.montreBalles();


}
//____________________________________
//CLASSE SYSTEME
//____________________________________
class Systeme {

int nb;
Balle[] table;
Vecteur[] coorda;

Systeme(int nb) {
  this.nb=nb;
  this.table = new Balle[nb];
  this.coorda=new Vecteur[nb];
  for(int i=0;i<nb;i++){
    float r =random(50,100);
    float x=random(-400+r,400-r);  float y=random(-400+r,400-r);  float z =random(-500+r,500-r);
    float vx=random(20,50);  float vy=random(35,50);  float vz=random(10,50);
    this.table[i]=new Balle(i,r,new Vecteur(x,y,z),new Vecteur(vx,vy,vz));
    this.coorda[i]=new Vecteur(0,0,0);
  }
}

void montreBox(){

stroke(255,150,150);
lights();
  fill(150,150,255,120);
  box(800,800,1000);
  push(); fill(250,50,55,100);noLights();
  translate(400,0,0);rotateY(HALF_PI);rect(0,0,1600,1600);pop();
  push();fill(250,250,0,70);
  translate(0,400,0);rotateX(HALF_PI);rect(0,0,1600,1600);pop();
 line(400,400,-800,400,400,800);
   //les ombres
 
  noStroke(); 
   for(int i=0;i<nb;i++){ 
    fill(table[i].cl.x,table[i].cl.y,table[i].cl.z,40);
   push();translate(400,table[i].pos.y,table[i].pos.z);rotateY(HALF_PI);
   float rap=4-table[i].pos.y/100;
   ellipse(0,0,table[i].r*rap,table[i].r*rap);pop();
    rap=4-table[i].pos.x/100;
    push();translate(table[i].pos.x,400,table[i].pos.z);rotateX(HALF_PI);
   ellipse(0,0,table[i].r*rap,table[i].r*rap);pop();
  
  coorda[i]=table[i].pos.composantesAbs();
  } 
 //
}

void montreBalles(){

  for(int i=0;i<nb;i++){push();
   translate(coorda[i].x,coorda[i].y,coorda[i].z);
    fill(table[i].cl.x,table[i].cl.y,table[i].cl.z);noStroke();
    ellipse(0,0,2*table[i].r,2*table[i].r);
   
     fill(table[i].cl.x+20,table[i].cl.y+20,table[i].cl.z+20);
    ellipse(table[i].r*0.1,table[i].r*0.1,table[i].r*1.7,table[i].r*1.7);
        fill(220,220,125);
    ellipse(table[i].r*0.4,table[i].r*0.4,table[i].r*0.5,table[i].r*0.5);
  
    pop();
  }
}

void controleChocs(Vecteur g){
for(int i=0;i<nb;i++){println(g.x+"   "+g.y+"   "+g.z);
  table[i].vit=table[i].vit.ajouter(g,table[i].tempo);
 table[i].vit.multiplier( 0.988);
  table[i].pos=table[i].pos.ajouter(table[i].vit,1);
  table[i].limite();}
  for(int i=0;i<nb;i++){
    for(int j=i+1;j<nb;j++){
      float d=table[i].pos.distance(table[j].pos);
    if(d<table[i].r+table[j].r){calculChoc(i,j);};
    }
  }
}

void calculChoc(int i,int j) {
  Vecteur abd=table[j].pos.ajouter(table[i].pos,-1);
  //vecteur normé orthogonal au plan de contact
  abd.normer();
  //rapport des masses
  float rm =table[i].m/table[j].m;
  float  rpr=table[i].r+table[j].r;
  float e = table[i].amorti;
  float V1scalN = table[j].vit.produitscalaire(abd);
  float V2scalN = table[i].vit.produitscalaire(abd);
  float vitessN = (1-rm*e)/(1+rm)*V1scalN+rm*(1+e)/(1+rm)*V2scalN;
  table[j].vit.x = vitessN*abd.x+table[j].vit.x-V1scalN*abd.x;
  table[j].vit.y = vitessN*abd.y+table[j].vit.y-V1scalN*abd.y;
  table[j].vit.z = vitessN*abd.z+table[j].vit.z-V1scalN*abd.z;
  float vitessN1 = (1+e)/(1+rm)*V1scalN+(rm-e)/(1+rm)*V2scalN;
  table[i].vit.x = vitessN1*abd.x+table[i].vit.x-V2scalN*abd.x;
  table[i].vit.y = vitessN1*abd.y+table[i].vit.y-V2scalN*abd.y;
  table[i].vit.z = vitessN1*abd.z+table[i].vit.z-V2scalN*abd.z;
  table[j].pos.x = table[i].pos.x+abd.x*rpr;
  table[j].pos.y = table[i].pos.y+abd.y*rpr;
  table[j].pos.z = table[i].pos.z+abd.z*rpr;
}

}
//____________________________________
//CLASSE BALLE
//____________________________________
class Balle{

Vecteur pos,vit;
float r,numero,amorti,tempo,m;
Vecteur cl;
public Balle(int numero,float r,Vecteur pos,Vecteur vit){
  this.pos=pos;
  this.vit=vit;
  this.amorti=1;
  this.tempo=0.01;
  this.numero=numero;
  this.r=r;
  this.m=r*r*r/1000;
  this.cl=new Vecteur((int)random(160),(int)random(160),(int)random(160));
}

void limite() {
  if (pos.x>400-r) {
    pos.x = 400-r;
    vit.x *= -1;
  }
  if (pos.x<-400+r) {
    pos.x = -400+r;
    vit.x *= -1;
  }
  if (pos.y>400-r) {
    pos.y = 400-r;
    vit.y *= -1;
  }
  if (pos.y<-400+r) {
    pos.y = -400+r;
    vit.y *= -1;
  }
  if (pos.z>500-r) {
    pos.z = 500-r;
    vit.z *= -1;
  }
  if (pos.z<-500+r) {
    pos.z = -500+r;
    vit.z *= -1;
  }
}

}
//____________________________________
//CLASSE VECTEUR
//____________________________________
class Vecteur{

float x,y,z;

public   Vecteur(float x1,float y1,float z1){
  this.x=x1;
  this.y=y1;
  this.z=z1;
}

public  Vecteur(){
  x=0;
  y=0;
z=0;}

void normer(){
  float lg=(float) Math.sqrt(x*x+y*y+z*z);
if(lg!=0) {	    x/=lg;	    y/=lg;	    z/=lg;}
}

Vecteur anguler(){
  float alfa=(float) Math.atan2(y,x);
  float beta=(float) Math.atan2(z,Math.sqrt(x*x+y*y));
  return (new Vecteur(0,beta,alfa));
}

float produitscalaire(Vecteur v){
return x*v.x+y*v.y+z*v.z;}

Vecteur produitvectoriel(Vecteur w){
  Vecteur p=new Vecteur(0,0,0);
  p.x=y*w.z-w.y*z;
  p.y=z*w.x-w.z*x;
  p.z=x*w.y-w.x*y;
  return p;
}
float distance(Vecteur v){
  float dis=ajouter(v,-1).longueur();
  return dis;
}
float longueur(){
return dist(0,0,0,x,y,z);}

void multiplier(float m){
  x*=m;y*=m;z*=m;
}

Vecteur ajouter(Vecteur v,float m){
  Vecteur res=new Vecteur(x+v.x*m, y+v.y*m,z+v.z*m);
  return res;
}
Vecteur composantesAbs(){
  float xx=objectX(x,y,z);
  float yy=objectY(x,y,z);
  float zz=objectZ(x,y,z);
  return new Vecteur(xx,yy,zz);
}

}